4 Argument Keywords

An argument keyword is a dummy argument name, followed by =, that appears in an actual argument list to identify the actual argument. In the absence of argument keywords, actual arguments are matched to dummy arguments by their position in the actual argument list; however, when argument keywords are used, the actual arguments may appear in any order. This is particularly convenient if some of the arguments are optional and are omitted. An actual argument list may contain both positional and keyword arguments; the positional arguments appear first in the list. If an argument keyword is used in a reference to a user-defined procedure, the procedure interface must be explicit. Argument keywords are specified for all intrinsic procedures.

Examples:

! Interface for subroutine DRAW
INTERFACE                        
   SUBROUTINE DRAW (X_START, Y_START, X_END, Y_END, FORM, SCALE)
      REAL X_START, Y_START, X_END, Y_END
      CHARACTER (LEN = 6), OPTIONAL :: FORM
      REAL, OPTIONAL :: SCALE
   END SUBROUTINE DRAW
END INTERFACE

! References to DRAW
CALL DRAW (5., -4., 2., .6, FORM = "DASHED")
CALL DRAW (SCALE=.4, X_END=0., Y_END=0., X_START=.5, Y_START=3.)

! References to intrinsics LBOUND, UBOUND, SIZE, and PRODUCT
REAL A (LBOUND (B, DIM=1) : UBOUND (B, DIM=1), SIZE (B, DIM=2) )
A_PROD = PRODUCT (A, MASK = A > 0.0 )

Tip: Argument keywords can enhance program reliability and readability. Program construction is easier when the strict ordering of arguments can be relaxed.

Related Topics:

Argument Association
Functions
Generic Procedures and Operators
Interfaces and Interface Blocks
Internal Procedures
Module Procedures
OPTIONAL Attribute and Statement
Subroutines

To Read More About It:

ISO 1539 : 1991, Fortran Standard, 12.4.1, 13.3
Fortran 90 Handbook, 12.5.4
Programmer's Guide to Fortran 90, 3.3.6

A keyword argument is one of:

keyword = expression

keyword = procedure-name

where a keyword is a dummy argument name.

Things To Know:

1. If an argument keyword is used in a reference to a procedure, the procedure interface must be explicit; that is, the procedure must be:
• an intrinsic procedure,
• an internal procedure,
• a module procedure, or
• an external procedure (or dummy procedure) with an interface block accessible to the program unit containing the reference.
Statement function references cannot use keyword calls.
2. After the first appearance of a keyword argument in an actual argument list, all subsequent arguments must use the keyword form.
3. If an optional argument is omitted, the keyword form is required for any following arguments.
4. In an interface block for an external procedure, the keywords do not have to be the same as the dummy argument names in the procedure definition. The keyword names can be tailored to fit their use in the referencing program unit.
5. The positional form is required for alternate returns, because the keyword must be a dummy argument name.
6. When choosing argument keyword names for generic procedures, care must be taken to avoid any ambiguity in the resolution of a generic reference to a specific procedure (see Generic Procedures and Operators, item 2 of the Things to Know).